General ASP script tips:

- Always buffer scripts. Are you still using Windows NT then turn on buffering in IIS – or enable buffering in each script by using: response.buffer = true. This is not needed in Windows 2000/2003 because buffering is enabled by default.

- Always use Option Explicit.

- Don’t put objects in the application and session scope – unless you know what you are doing and that it is the best solution.

- minimize session variables. Consider alternatives such as cookies, store in database, save to harddisk.

- Don’t mix scripting languages.

- Don’t mix ASP and HTML. If you need to then include HTML in response.write’s.

- Keep files as small as possible. This means: Learn to code proper HTML using W3C standards. Use CSS classes, no inline styles.

- Re-use code. Put common functions in global include files.

- Use COM objects instead of ASP whenever possible.

- Instead of normal ASP scripts use VBScript classes (if you can’t use COM objects).

- Don’t request the same values over and over again. Example:

if dbrs.fields("Drink").value = "Milk" Then
   Accept(false)
elseif dbrs.fields("Drink").value = "Water" Then
   SaveForLater()
elseif dbrs.fields("Drink").value = "Wine" Then
   CheckWineLabel()
elseif dbrs.fields("Drink").value = "Beer" Then
   do until drunk
       Drink()
       GetNewBeer()
   loop
else
   response.write "Unknown liquid"
end if

Instead use:

Dim value
value = dbrs.fields("Drink").value
If value = "Milk" Then .....

- Explicitly set what you want to retrieve. Instead of:

querystring_value = request("var1")
recordset_value = dbrs("Fieldname")

use:

querystring_value = request.querystring.item("var1")
recordset_value = dbrs.fields.item("Fieldname").value

In some cases there will be a default property, but if not then ASP has to loop through all possible properties to find what you are looking for. In the case of the Request object, ASP has to loop through the form, querystring, cookies, clientCertificate and serverVariables collections to find the variable. With ADO Recordset I am not sure if this is relevant, I think the fields collection is the default and the property collection is ignored – but I don’t know.

- Keep your code structured.

- Comment your code.

In ASP and HTML there are a couple of things we must to do serve up UTF-8:

ASP CODE:

Response.ContentType = "text/html"
Response.AddHeader "Content-Type", "text/html;charset=UTF-8"
Response.CodePage = 65001
Response.CharSet = "UTF-8"

and the following HTML META tag:

<meta http-equiv="Content-Type" content="text/html;charset=UTF-8" />

We are using Microsoft SQL Server as a database. While it stores data as UCS-2 (Unicode) in Unicode fields (nchar/nvarchar/ntext), I have encountered problems with saving data in Chinese. It seems I have to use N prefix in front of all columns – i.e. UPDATE Table SET Field = N’Unicode Value’;. I am currently checking more around this issue. I really hope I don’t need to do this, if so I must say I am very disappointed with SQL Server – with Oracle this would not have been a problem.

For right-to-left languages we can use a property in CSS called direction, also you can read more about Right-To-Left text in markup languages here.

First tip is the best way to get data from SQL Server. Most people use ADO Recordset and loop through it. This means you have a connection to the SQL Server open while executing the script. A much better way is to use the GetRows() function in ADO:

Dim db, dbrs, sql, ConnString, users, user

ConnString = "DSN=YourDSN;"
sql = "SELECT UserId, Username FROM Users ORDER BY Username;"

' GET DATA
set db = server.createobject("ADODB.Connection")
db.open ConnString
set dbrs = server.createObject("ADODB.Recordset")
dbrs.open sql, db
if NOT dbrs.eof then
    users = dbrs.GetRows()
end if
db.close
set db = nothing

' DISPLAY DATA
for user = lbound(users,2) to ubound(users,2)
   response.write "UserId: " & users(0,user)
   response.write "Username: " & users(1,user)
   response.write vbNewLine
next

From the ADO Documentation:

Use the GetRows method to copy records from a Recordset into a two-dimensional array. The first subscript identifies the field and the second identifies the record number. The array variable is automatically dimensioned to the correct size when the GetRows method returns the data.

Since it’s a two-dimensional array we need to get the lower and upper bound of the array using: lbound(users,2). Using those values we loop from the first item to the last item.

The current record is the user variable. To get the field we want we must get it according to the index entered in the SQL Query:

SELECT UserId, Username..

UserId: 0

UserName: 1

and so on.

This can be confusing if you do changes to the SQL Query – then you must go through your code and update the array index for the fields! A solution to that is to create costants for each field name:



Dim UserId

Const UserId = 0



Lessons learned:

1. Use ADO GetRows() to get data.
2. Initiate objects as late as possible and release objects as early as possible.
3. Use variable for SQL query. Easier for debugging.
4. Declare all variables at the top of the script/function/class.

dim objXMLHTTP, url
set objXMLHTTP = server.CreateObject("MSXML2.ServerXMLHTTP.4.0")
url = "http://yourserver.com/file.html"
objXMLHTTP.Open "GET", url, false
objXMLHTTP.Send()
response.Write objXMLHTTP.responseText
set objXMLHTTP = nothing

Note: This is for use with ASP. Notice the Server in the object. That’s the server-safe version of XMLHTTP. When using client-side JavaScript use the MSXML2.XMLHTTP.4.0 instead. Also remember that there are many versions of the XML Parser around, so don’t use the 4.0 version if the user doesn’t have it installed. I recommend using the MS XML Parser sniffer to get the correct version installed – see my article here.

See this page at PerfectXML for more information.

1.

Problem: When the user see an error in the application, the user becomes unhappy and it results in a negative experience with the product. If this hapens often it will lead to the customer becoming unsatisfied and it addition it will hurt the brand image.

Our solution: When an error occurs a custom and a pleasant error page is displayed. It will alert the user that an error occurred and that it has been logged to a database. This gives the user confidence that the error will be fixed. It is also much better to view a relatively nice error page than a broken document with an ugly ASP error in the middle of the page.

2.

Problem: An error means a system bug. Most bugs are left unreported by user. For a developer it can be close to impossible to find and track all bugs.

Our solution: Using an error logging tool which logs all errors occurred to a database, developers have overview of when and where the error occurred, what the error message was, what input variables was given to the script and which user who executed the script. In most cases this will give the developer enough information to fix the error straight away or test the script and understand the cause of the error.

3.

Problem: When a user received an error when working with an important task or if the error repeats itself then the user calls customer service. Having worked in customer service earlier I know how difficult it is to get a clear overview of the user is doing and what the error is. When the developer gets the error report it is very hard to track and debug the error.

Our solution: When the user receives an error, the user is presented with an option to contact customer service through a form. This form automatically fills out the error reference. In addition the error reference number is displayed for the user so he/she can quote it when calling customer service. This results in the developer being able to pinpoint the error that occurred making the process much quicker and keeping the customer happy.

So how do we do this in practice?

1. Set up a custom error page in IIS. Create a page in your web-application, i.e. /system/error.asp. Have IIS execute this page when 500 and 500.100 error occurs. For more information see this MSDN article. The article covers how to implement a custom 404 page, but it’s the same with 500/500.100 pages, just select those from the list instead. I recommend that you set up a custom 404 page as well.

2. When that is done try to view a script with an error in your web-application. See it will redirect to the /system/error.asp page.

3. Next task is to create the error.asp page. First thing to do is design it with information that shall be displayed to the user. Then comes the scripting part:

Make sure you include response.clear at the top of the script. This is because when an error occurs IIS is doing a server.execute(“/system/error.asp”), thus all the contents from the script where the error occurred will be included unless the response is cleared.

then we get all the information about the error using the ASP error object:

	dim objErr, err_asp_desc, err_desc, err_no, err_src, err_line
	dim err_col, err_page, err_cat, err_asp_code, err_input, err_script
	set objErr = server.GetLastError()
	if objErr.Number <> 0 then
		err_asp_desc = objErr.ASPDescription
		err_desc = objErr.Description
		err_no = objErr.Number
		err_src = objErr.Source
		err_line = objErr.Line
		err_col = objErr.Column
		err_page = objErr.File
		err_cat = objErr.Category
		err_asp_code = objErr.ASPCode
		err_input = request.ServerVariables.Item("QUERY_STRING")
		err_script = request.ServerVariables.Item("SCRIPT_NAME")
	end if
	set objErr = Nothing

See there are scripts here. That is because when using an include file, the ASP error object will report the name of the include file if that is where the error occurred. But many times the script which holds the reference to the include file is the reason for the error, thus we need to get the script name as well.

The next task is to log this error to the database:

	dim c_db, sql, RefId, c_dbrs
	set c_db = server.CreateObject("ADODB.Connection")
	c_db.Open Application("ConnString")
	sql = "INSERT INTO Website_Error (ErrorNumber, ErrorDesc, Script, ErrorScript, QueryString, ErrorLine, ErrorColumn, ErrorCategory, ErrorSource, ASPError, ASPDescription, IP, UserId, ContactId) VALUES (" & err_no & ", '" & err_desc & "', '" & err_script & "', '" & err_page & "', '" & err_input & "', " & err_line & ", " & err_col & ", '" & err_cat & "', '" & err_src & "', '" & err_asp_code & "', '" & err_asp_desc & "', '" & request.ServerVariables.Item("REMOTE_ADDR") & "');"
	c_db.Execute(sql)
	sql = "SELECT @@Identity FROM Website_Error;"
	set c_dbrs = c_db.Execute(sql)
	RefId = c_dbrs.fields.item(0).value
	c_dbrs.close
	set c_dbrs = nothing
	c_db.Close
	set c_db = Nothing

The RefId is used to identify the error. This can be displayed to the user the user can quote this reference id when contacting customer service.

And there you have it – a custom error page with error logging!

- Stable, robust. Able to send a lot of email.

- Mail merge.

- Mass mailing.

- Send embedded images (CID).

- Queing.

- Send email with both html and plain text in same email.

We are using ASP 3.0 (but looking into ASP.NET) and COM.

We are now using DynuEmail, but it lacks these features. So far my list includes: w3 Jmail from Dimac, SoftArtisans SMTP Mail and ASPEmail. We used Jmail before but it was not stable (earlier version) and we did not receive support from Dimac, so i don’t think we will look much into that one.

First we open a ADO connection and recordset just like we normally do.

' OPEN REPORT IN RECORDSET
set c_db = server.CreateObject("ADODB.Connection")
c_db.ConnectionString = Application.Contents.Item("ConnString")
c_db.Open()
Set ObjADORS = Server.CreateObject("ADODB.Recordset")
ObjADORS.Open sql, c_db,adOpenStatic,adLockReadOnly
set objStream = server.CreateObject("ADODB.Stream")
objStream.Charset = "ISO-8859-1"
' SAVE RECORDSET TO ADO STREAM AS XML
ObjADORS.Save objStream, adPersistXML
ObjADORS.Close
Set ObjADORS = Nothing
c_db.Close
set c_db = nothing

Look at the code above and youl will recognise all lines except for one – objADORS.Save objStream.adPersistXML. What i am doing is saving the ADO Recordset to ADO Stream, but not as ADO Recordset but in XML format (adPersistXML).

The next thing we need to do is get the XSLT and transform the XML using the XSLT:

' LOAD XSLT
set objXSLT = server.CreateObject("MSXML2.FreeThreadedDOMDocument.4.0")
objXSLT.createProcessingInstruction "xml", "version=""1.0"" encoding=""ISO-8859-1"""
objXSLT.async = false
objXSLT.load("file.xslt")

' LOAD THE XSLT TEMPLATE TRANSFORMER
set objXSLTTemplate = server.CreateObject("MSXML2.XSLTemplate.4.0")
objXSLTTemplate.stylesheet = objXSLT
set objXSLT = Nothing

' Load the XSLT processor
set xmlPro = objXSLTTemplate.createProcessor()
set objXSLTTemplate = Nothing

' USE THE ADO STREAM
xmlPro.input = objStream
objStream.Close
set objStream = Nothing
set objXMLDOM = Nothing

' Output to response
xmlPro.output = Response
' Transform XML using XSLT
xmlPro.transform
set xmlPRo = Nothing

The XSLT file looks like this:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:rs="urn:schemas-microsoft-com:rowset" xmlns:z="#RowsetSchema">

<xsl:output method="xml" media-type="text/xml" encoding="ISO-8859-1" />

<xsl:template match="/">

<xsl:element name="Entries">

<xsl:for-each select="//rs:data/z:row">

<xsl:element name="Entry">

<xsl:attribute&gt

<xsl:value-of select="@DatabaseFieldName"/>

</xsl:attribute>

</xsl:element>

</xsl:for-each>

</xsl:element>

</xsl:template>

</xsl:stylesheet>

What you need is the //rs:data/z:row – this will list all the fields in the recordset. The XSLT transformer will then populate the final XSLT document with values from the XML.